class ScaleObject extends Sprite
{
    /** Scale9grid pieces. **/
    private var _tl:Bitmap;
    private var _tc:Bitmap;
    private var _tr:Bitmap;
    private var _ml:Bitmap;
    private var _mc:Bitmap;
    private var _mr:Bitmap;
    private var _bl:Bitmap;
    private var _bc:Bitmap;
    private var _br:Bitmap;
   
    /** Constructor. **/
    public function ScaleObject(original:DisplayObject, scaleGrid:Rectangle)
    {
        _tl = slice(original, 0, 0, scaleGrid.left, scaleGrid.top);
        _tc = slice(original, scaleGrid.left, 0, scaleGrid.width, scaleGrid.top);
        _tr = slice(original, scaleGrid.right, 0, original.width - scaleGrid.right, scaleGrid.top);
       
        _ml = slice(original, 0, scaleGrid.top, scaleGrid.left, scaleGrid.height);
        _mc = slice(original, scaleGrid.left, scaleGrid.top, scaleGrid.width, scaleGrid.height);
        _mr = slice(original, scaleGrid.right, scaleGrid.top, original.width - scaleGrid.right, scaleGrid.height);
       
        _bl = slice(original, 0, scaleGrid.bottom, scaleGrid.left, original.height - scaleGrid.bottom);
        _bc = slice(original, scaleGrid.left, scaleGrid.bottom, scaleGrid.width, original.height - scaleGrid.bottom);
        _br = slice(original, scaleGrid.right, scaleGrid.bottom, original.width - scaleGrid.right, original.height - scaleGrid.bottom);
    }
   
    /** Create a slice. **/
    private function slice(original:DisplayObject, x:Number, y:Number, width:Number, height:Number):Bitmap
    {
        // render a slice of the original
        var bd:BitmapData = new BitmapData(width, height, true, 0);
        bd.draw(original, new Matrix(1, 0, 0, 1, -x, -y));
       
        // create and position the bitmap
        var bitmap:Bitmap = new Bitmap(bd, PixelSnapping.AUTO, true);
        bitmap.x = x;
        bitmap.y = y;
        addChild(bitmap);
       
        return bitmap;
    }
   
    /** Width. **/
    override public function set width(value:Number):void
    {
        _tc.width = _mc.width = _bc.width = value - _tl.width - _tr.width;
        _tr.x = _mr.x = _br.x = value - _tr.width;
    }
   
    /** Height. **/
    override public function set height(value:Number):void
    {
        _ml.height = _mc.height = _mr.height = value - _tl.height - _bl.height;
        _bl.y = _bc.y = _br.y = value - _bl.height;
    }
}