myCuePoints.addCuePoint( 2, "squid")
myCuePoints.addCuePoint( 3, "boat" );
myCuePoints.addCuePoint( 10, "spear");
myCuePoints.addCuePoint( 11, "bowl");

public function addCuePoint(cSeconds:Number, cEvent:String):void {
  cuePoints.push( cSeconds);
  cueEvents.push(cEvent);
}

var time:Number=playingTime.current;
var checkTime=Math.floor(pTime);
var test:Number = ArrayUtil.search( cuePoints, checkTime );

Tracing("time = "+ checkTime+ " , a cue @ " +cuePoint+ " for the " +cueEvent);

package code
{
    import fl.video.*;
    import flash.events.*;
    import flash.display.*;
    import flash.display.Sprite;
        import flash.net.navigateToURL;
        import flash.net.URLRequest;
   
    /********************************
    * SyncVideoPreso (document class)
    * The SyncVideoPreso class extends MovieClip
    * to create a simple synchronized video interface
    * on the main timeline of the FLA file. The class
    * may also be assigned to a symbol.
    * ---------------------
    * Developed by Dan Carr (dan@dancarrdesign.com)
    * For Adobe Systems, Inc., Flash Developer Center
    * Last modified: July 8, 2009
    */ 
    public class SyncVideoPreso extends MovieClip
    {
        //***************************
        // Properties:
       
        private var highlight_mc:MovieClip;
       
        //***************************
        // Constructor:
       
        public function SyncVideoPreso():void
        {
            // Listen for all clicks
            addEventListener(MouseEvent.CLICK, clickHandler);
           
            // Listen for cuepoints
            display.addEventListener(MetadataEvent.CUE_POINT, cuePointHandler);
        }
       
        //***************************
        // Event Handlers:
       
        // Create event handler functions to catch events from
        // the video component and update the interface...
       
        private function cuePointHandler( evt:MetadataEvent ):void
        {
            // Get the cue name from the event object
            synchVideoToInterace( evt.info.name );
        }
       
        // All button clicks pass through this event handler. Any
        // button ending in _btn is assumed to be a cuepoint button.
       
        private function clickHandler(event:MouseEvent):void
        {
            // Get button name
            var btnName:String = event.target.name;
            if( btnName.indexOf("_btn") != -1 )
            {
                // Seek to cuepoint
                seekToCuePoint(btnName.substr(0,-4));
            }
            if( btnName.indexOf("_link1") != -1 )
            {
            navigateToURL(new URLRequest("http://www.diabetesbehaviorchange.com"));
        }
        }
        //***************************
        // Public Methods:
       
        // Navigation buttons call this function to trigger a change
        // in the video and the view of the content
       
        public function seekToCuePoint( cueName ) : void
        {
            // Find the cue point in the FLVPlayback component, seek
            // to time, and highlight the next button for a quick redraw
            var c:Object = display.findCuePoint( cueName );
            if( c ){
                // Validate that the requested time has downloaded
                // in progressive video to avoid stalls in the playback.
                if(!display.isRTMP )
                {
                    var dltime:Number = display.totalTime * (display.bytesLoaded / display.bytesTotal);
                    if( dltime < c.time ){
                        return;
                    }
                }
                display.seekSeconds( c.time );
                findNextButton( c.name );
            }
        }
         
        // The natural flow through the video or jumping by seeking
        // forward and backward will trigger the following function
       
        public function synchVideoToInterace( cueName:String ):void
        {
            // Play if needed
            if(!display.isRTMP && !display.playing ){
                display.play();
            }
            // Go to labeled frame
            gotoAndStop( cueName );
           
            // Update the higlight position
            findNextButton( cueName );
        }
       
        // Layout the button highlight when requested
       
        public function findNextButton( cueName:String ):void
        {
            // Look for buttons named with the current cue point
            // name plus the letters '_btn' (i.e. introduction_btn)
            var cueBtn:DisplayObject = getChildByName(cueName+"_btn");
            if( cueBtn )
            {
                // Attach the highlight clip if needed
                if( highlight_mc == null ){
                    highlight_mc = new ThumbOutlineSelected();
                    addChild(highlight_mc);  
                    }
                highlight_mc.x = cueBtn.x;
                highlight_mc.y = cueBtn.y;
            }
        }
    }
   
   
}